Task 3.6 Gender

Neology and Gender Equality

This page describes the collection of concepts and lexemes worked on in ENEOLI Task 3.6, "Neology and Gender Equality".

SPARQL Queries

All Gender concepts and English description

#title: "Gender" concepts and English description

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/> 

select distinct ?concept ?conceptLabel ?termposLabel ?wikidata ?desc_en ?equiv ?lang 
(group_concat(?validator; SEPARATOR = ", ") as ?validated)

       
where {   
  ?concept endp:P82 enwb:Q51. # Concepts of the "gender" collection
  ?concept schema:description ?desc_en. filter(lang(?desc_en)="en")
  ?concept enp:P57 ?equiv_st. ?equiv_st enps:P57 ?equiv.
			   ?equiv_st enpq:P64 [rdfs:label ?validator]. filter(lang(?validator)="en") # has been validated.
               bind (lang(?equiv) as ?lang)
  optional {?concept endp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata)}
  optional {?concept endp:P92 ?termpos.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} group by ?concept ?conceptLabel ?termposLabel ?wikidata ?desc_en ?equiv ?lang ?validated
order by lcase(?conceptLabel)

Try it!

All Gender concepts and linked lexical entries

#title: "Gender" concepts and linked lexical senses

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/> 

select distinct ?concept ?conceptLabel ?termposLabel ?wikidata ?equiv ?lang 
(group_concat(?validator; SEPARATOR = ", ") as ?validated)
?lexeme_sense
       
where {   
  ?concept endp:P82 enwb:Q51. # Concepts of the "gender" collection
  ?concept enp:P57 ?equiv_st. ?equiv_st enps:P57 ?equiv.
			   ?equiv_st enpq:P64 [rdfs:label ?validator]. filter(lang(?validator)="en") # has been validated.
               bind (lang(?equiv) as ?lang)
  optional {?equiv_st enpq:P63 ?linked_sense. bind (iri(concat(str(enwb:),?linked_sense)) as ?lexeme_sense)}
  optional {?concept endp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata)}
  optional {?concept endp:P92 ?termpos.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} group by ?concept ?conceptLabel ?termposLabel ?wikidata ?equiv ?lang ?validated ?lexeme_sense
order by lcase(?conceptLabel) ?lang

Try it!

Coverage of languages (also unvalidated)

This query lists statistics of language coverage (concept labels and descriptions), taking into account all data, i.e. not only validated equivalents.

#title: "Gender" concepts: statistics of language coverage, labels and descriptions

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select distinct ?concept ?conceptLabel ?termposLabel ?wikidata ?engDef 
(count(distinct ?label) as ?labels) 
(group_concat(distinct?label_lang;SEPARATOR=", ") as ?label_langs)
(count(distinct ?desc) as ?descs)
(group_concat(distinct?desc_lang;SEPARATOR=", ") as ?desc_langs)
       
where { 
  
    
  ?concept endp:P82 enwb:Q51. # Concepts of the Task 3.6 "Gender" collection
  ?concept rdfs:label ?label; schema:description ?desc.
  bind(lang(?label) as ?label_lang) bind(lang(?desc) as ?desc_lang)
  optional {?concept endp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata)}
  optional {?concept endp:P92 ?termpos.}
  optional {?concept schema:description ?engDef. filter(lang(?engDef)="en")}
 
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} group by ?concept ?conceptLabel ?termposLabel ?wikidata ?engDef ?labels ?label_langs ?descs ?desc_langs
order by lcase(?conceptLabel)

Try it!

Lexical entries

This query lists lexical entries in this collections, and their links to concepts.

#title: "Gender" lexical entries with linked concepts (and wikidata concepts)
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
PREFIX enpr: <https://eneoli.wikibase.cloud/prop/reference/>

select distinct ?lexical_entry ?lemma (lang(?lemma) as ?langcode) ?langLabel ?posLabel ?sense ?concept ?wikidata

where { 
  ?lexical_entry endp:P82 enwb:Q51. # Entries in the Task 3.6 "Gender" collection
  ?lexical_entry wikibase:lemma ?lemma; dct:language ?lang; ontolex:sense ?sense; wikibase:lexicalCategory ?pos.
  ?sense endp:P12 ?concept.
  optional {?concept endp:P1 ?wikidata.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} 
order by ?lang lcase(?lemma)

Try it!

This query lists those lexical entries that have attestations. It shows the first attestation for every entry.

#title: "Gender" lexical entries with attestations: first attestation only

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
PREFIX enpr: <https://eneoli.wikibase.cloud/prop/reference/>

select distinct ?conceptLabel ?lexical_entry ?lemma ?langLabel ?sense ?concept ?attestation ?source (year(?date) as ?year)

where { 
  ?lexical_entry endp:P82 enwb:Q51. # Entries in the Task 3.6 "Gender" collection
  ?lexical_entry wikibase:lemma ?lemma; dct:language ?lang; ontolex:sense ?sense.
  ?sense endp:P12 ?concept.
  { select ?lexical_entry ?attestation ?date ?source where {
  ?lexical_entry enp:P94 [enps:P94 ?attestation; enpq:P96 ?date; prov:wasDerivedFrom [enpr:P95 ?source]].}
   order by ?date limit 1 }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} 
order by lcase(?lemma)

Try it!

Lexical entries and their links to lexical innovation processes

This query lists those lexical entries that are linked to a lexical innovation process.

#defaultView:Graph
#title: Neologisms of the "Gender" collection and their links to lexical innovation processes

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?subject ?subjectLabel ?rgb ?object ?objectLabel 

where {
  { ?subject endp:P4* enwb:Q1731; endp:P4 ?object. } 
  union
  { ?subject endp:P82 enwb:Q51; endp:P84 ?object; wikibase:lemma ?lemma. bind(concat(ucase(lang(?lemma)),": ",str(?lemma)) as ?subjectLabel) bind("00EE76" as ?rgb)}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en, fr". }
}

Try it!