Neologisms

Neologisms on ENEOLI Wikibase

We have created a few example entries, which are modelled as following:

• A neologism has its own Lexical Entry
• A neologism is described with the property "neologism type"
• A neologism is described with the property "lexical innovation process type"
• A neologism has one or more senses
  • Each sense has a short gloss
  • Each sense can be linked to a conceptual item (stemming from Wikidata or created new)

SPARQL

#title: Neologisms described in ENEOLI Wikibase

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
PREFIX enpr: <https://eneoli.wikibase.cloud/prop/reference/>
PREFIX enno: <https://eneoli.wikibase.cloud/prop/novalue/>

select ?neologismEntry ?lemma ?neolLangLabel ?neolTypeLabel ?neolProcessTypeLabel (group_concat(?sourceLem; SEPARATOR=", ") as ?sourceLemma) ?senseConcept ?senseConceptWikidata
       
where { 
  ?neologismEntry endp:P5 enwb:Q50; wikibase:lemma ?lemma; dct:language ?neolLang.
  optional {?neologismEntry endp:P83 ?neolType.}
  
  optional {?neologismEntry enp:P84 ?proc_st. ?proc_st enps:P84 ?neolProcessType.
            optional {                       
             ?proc_st enpq:P85 ?sourceLexeme. ?sourceLexeme wikibase:lemma ?sourceLex.
                    bind(concat(str(?sourceLex), " (",lang(?sourceLex),")") as ?sourceLem)}
           }
  optional {?neologismEntry ontolex:sense [endp:P12 ?senseConcept]. ?senseConcept endp:P1 ?wd.
            bind (iri(concat("http://www.wikidata.org/entity/",?wd)) as ?senseConceptWikidata) }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?neologismEntry ?lemma ?neolLangLabel ?neolTypeLabel ?neolProcessTypeLabel ?sourceLemma ?senseConcept ?senseConceptWikidata
order by lcase(str(?lemma))

Try it!