NeoVoc hierarchy of Lexical Innovation Processes

From eneoli wikibase

Hierarchy of Lexical Innovation Process and Result concepts in NeoVoc

The conceptual organization of lexical innovation processes builds on Sableyrolles & Pruvost's work (2016) as a starting point.

Many NeoVoc concepts describe either (a) types of Lexical Innovation Process, or (b), types of results of Lexical Innovation (i.e., neologism types).

Both Lexical Innovation Process concepts and Lexical Innovation Result concepts should be linked to (a subclass of) Lexical Innovation Process, or to Lexical Innovation Result, respectively, using the property subclass of (P4).

A Lexical Innovation Process concept should be linked to its corresponding Lexical Innovation Result concept, using the property has result (P69).

Database queries

Subclasses (kinds of) "neologism" = "lexical innovation result" (table view)

#title: Subclasses (kinds of) "neologism" and their direct superclasses

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?subject ?subjectLabel ?directSuperClassLabel

where {
  
  ?subject endp:P4* enwb:Q15; endp:P4 ?directSuperClass.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en, fr". }
}

Try it!

Subclasses (kinds of) "neologism" = "lexical innovation result" (table view, narrowest only)

#title: Subclasses (kinds of) "neologism": only narrowest (leaves of the tree with root "neologism")

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select distinct
?subjectLabel ?subjectDescription ?subject 

where {
  
  ?subject endp:P4* enwb:Q15. filter not exists {?narrower endp:P4 ?subject.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en, fr". }
} order by lcase(?subjectLabel)

Try it!


Subclasses (kinds of) "lexical innovation process" (graph view)

This query returns a graph visualisation. The node Q1731 ("lexical innovation process", a.k.a. "lexicogenic matrix") is the root if this tree-like structure. The most fine-grained concepts (the leaves of the tree), are coloured green. 

#defaultView:Graph
#title: Hierarchy tree of Lexical Innovation Processes

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?object ?objectLabel ?subject ?subjectLabel ?rgb ?edgeLabel

where { values ?edge {enwb:P4}
  ?edge wikibase:directClaim ?claim.
  ?subject endp:P4* enwb:Q1731; ?claim ?object. bind("CCFFE5" as ?rgb)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en, fr". }
}

Try it!


Subclasses (kinds of) "lexical innovation result" (graph view)

This query returns a graph visualisation. The node Q15 ("lexical innovation result", a.k.a. "neologism") is the root if this tree-like structure. The most fine-grained concepts (the leaves of the tree), are coloured green. 

#defaultView:Graph
#title: Subclasses (kinds of) "lexical innovation result"

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?object ?objectLabel ?subject ?subjectLabel ?rgb

where {
  
  ?subject endp:P4* enwb:Q15; endp:P4 ?object. bind("CCFFE5" as ?rgb)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en, fr". }
}

Try it!


Lexical innovation PROCESS or RESULT?

#title: NeoVoc concepts: lexical innovation PROCESS or RESULT?

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?concept ?wikidata ?label_en ?label_fr ?process_or_result ?class ?classLabel

where { values ?proc_or_res {enwb:Q1731 enwb:Q15}
  
  ?concept endp:P4+ ?proc_or_res. ?proc_or_res rdfs:label ?process_or_result. filter(lang(?process_or_result)="en")
  ?concept endp:P4 ?class.
  optional {?concept endp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  ?concept rdfs:label ?label_en. filter(lang(?label_en)="en")
  ?concept rdfs:label ?label_fr. filter(lang(?label_fr)="fr")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?process_or_result ?label_en

Try it!


Concepts without classification as lexical innovation process or result

These concepts still need a subclass of statement pointing to either to (a subclass of) Lexical Innovation Process, or to Lexical Innovation Result, in case they are to be classified in that way. 

#title: NeoVoc concepts with missing classification as (subclass of) lexical innovation PROCESS or RESULT

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select distinct
?concept ?wikidata ?label_en ?label_fr

where { values ?proc_or_res {enwb:Q1731 enwb:Q15}
  
  ?concept endp:P5 enwb:Q12.
  filter not exists {?concept endp:P4+ ?proc_or_res.}
  optional {?concept endp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  ?concept rdfs:label ?label_en. filter(lang(?label_en)="en")
  ?concept rdfs:label ?label_fr. filter(lang(?label_fr)="fr")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?label_en

Try it!


Concepts classified as lexical innovation process, and concepts describing the corresponding results

#title: NeoVoc concepts: lexical innovation PROCESSes and their RESULTs

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?process ?processLabel ?processTypeLabel ?result ?resultLabel 
where { 
  ?process endp:P4 ?processType; endp:P69 ?result. # instances of "NeoVoc Concept"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
}

Try it!


Concepts classified as lexical innovation process, missing a link to the corresponding result concept

#title: NeoVoc concepts: lexical innovation PROCESS without corresponding RESULT

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?process ?processLabel ?subclass_ofLabel
where { 
  ?process endp:P4 ?subclass_of; endp:P4+ enwb:Q1731.
  filter not exists {?narrower endp:P4 ?process.}
  filter not exists {?process endp:P69 ?result.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
}

Try it!


Concepts classified as lexical innovation result, missing a link from the corresponding process concept

#title: NeoVoc concepts: lexical innovation RESULT without corresponding PROCESS

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?result ?resultLabel
where { 
  ?result endp:P4+ enwb:Q15.
  filter not exists {?process endp:P69 ?result.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
}

Try it!

Lexical Innovation Result (a.k.a. neologism type) hierarchy

#title: NeoVoc concepts: lexical innovation RESULTs hierarchy
#defaultView:Graph
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
select
?result ?resultLabel ?directSuperClass ?directSuperClassLabel
where { 
  ?result endp:P4* enwb:Q15.
  ?result endp:P4 ?directSuperClass .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,fr". }
} order by ?directSuperClass ?result

Try it!


concepts classified as lexical innovation PROCESS or as RESULT (=Neologism), and their direct superclasses

#title: NeoVoc concepts classified as lexical innovation PROCESS or as RESULT (=Neologism), and their direct superclasses

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select distinct
?concept ?label_en ?desc_en ?subclass_of ?process_or_neologism

where { 
  ?concept endp:P82 enwb:Q12.
  ?concept endp:P4 [rdfs:label ?subclass_of]. filter(lang(?subclass_of)="en")
  optional {?concept endp:P4+ ?proc_or_neol. ?proc_or_neol endp:P5 enwb:Q17; rdfs:label ?process_or_neologism. filter(lang(?process_or_neologism)="en")}
  ?concept rdfs:label ?label_en. filter(lang(?label_en)="en")
  ?concept schema:description ?desc_en. filter(lang(?desc_en)="en")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} 
order by lcase(?label_en)

Try it!


Neologisms and their links to lexical innovation process types

#defaultView:Graph
#title: Neologisms and their links to lexical innovation process types

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?subject ?subjectLabel ?rgb ?object ?objectLabel 

where {
  { ?subject endp:P4* enwb:Q1731; endp:P4 ?object. } 
  union
  { ?subject endp:P84 ?object; wikibase:lemma ?lemma. bind(concat(ucase(lang(?lemma)),": ",str(?lemma)) as ?subjectLabel) bind("00EE76" as ?rgb)}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en, fr". }
}

Try it!

Neologisms and their links to neologism types

#defaultView:Graph
#title: Neologisms and their links to lexical innovation result types, including "source lexeme" relations

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?subject ?subjectLabel ?rgb ?object ?objectLabel 

where {
  { ?subject endp:P4* enwb:Q15; endp:P4 ?object. } 
  union
  { ?subject endp:P83 ?object; wikibase:lemma ?lemma. bind(concat(ucase(lang(?lemma)),": ",str(?lemma)) as ?subjectLabel) bind("00EE76" as ?rgb)}
  union
  { ?subject endp:P85 ?object; wikibase:lemma ?lemma. bind(concat(ucase(lang(?lemma)),": ",str(?lemma)) as ?subjectLabel) bind("00EE76" as ?rgb)}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en, fr". }
}

Try it!

Retrieved from "https://eneoli.wikibase.cloud/w/index.php?title=NeoVoc_hierarchy_of_Lexical_Innovation_Processes&oldid=68450"