ENEOLI Training School 2025

ENEOLI Training School 2025

This page describes the collection of concepts and lexemes worked on at the ENEOLI 2025 Training School, Lisbon (day 5).

SPARQL Queries

Lexical entries

This query lists all lexical entries in this collection. It shows the oldest attestation for every entry.

#title: "Training collection" lexical entries with attestations: first attestation only

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
PREFIX enpr: <https://eneoli.wikibase.cloud/prop/reference/>

select distinct ?conceptLabel ?lexical_entry ?lemma ?langLabel ?sense ?concept ?attestation ?source (year(?date) as ?year)

where { 
  ?lexical_entry endp:P82 enwb:Q50. # Entries in the "Training" collection
  ?lexical_entry wikibase:lemma ?lemma; dct:language ?lang.
  optional { ?lexical_entry ontolex:sense ?sense.
  optional { ?sense endp:P12 ?concept. }}
  optional { select ?lexical_entry ?attestation ?date ?source where {
  ?lexical_entry enp:P94 [enps:P94 ?attestation; enpq:P96 ?date; prov:wasDerivedFrom [enpr:P95 ?source]].}
   order by ?date limit 1 }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} 
order by lcase(?lemma)

Try it!

Lexical entries and their links to lexical innovation processes

This query lists those lexical entries that are linked to a lexical innovation process.

#defaultView:Graph
#title: Neologisms of the "Training" collection and their links to lexical innovation processes

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>

select
?subject ?subjectLabel ?rgb ?object ?objectLabel 

where {
  { ?subject endp:P4* enwb:Q1731; endp:P4 ?object. } 
  union
  { ?subject endp:P82 enwb:Q50; endp:P84 ?object; wikibase:lemma ?lemma. bind(concat(ucase(lang(?lemma)),": ",str(?lemma)) as ?subjectLabel) bind("00EE76" as ?rgb)}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en, fr". }
}

Try it!

Lexical entries and senses linked to concepts

This query lists those lexical entries with one or more senses linked to concepts.

#title: "Training collection" lexical entries with senses linked to concepts

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/>
PREFIX enpr: <https://eneoli.wikibase.cloud/prop/reference/>

select distinct ?lexical_entry ?lemma ?langLabel ?sense ?concept (iri(concat(str(wd:),?wd)) as ?wikidata_concept)

where { 
  ?lexical_entry endp:P82 enwb:Q50. # Entries in the "Training" collection
  ?lexical_entry wikibase:lemma ?lemma; dct:language ?lang.
  ?lexical_entry ontolex:sense ?sense.
  ?sense endp:P12 ?concept. 
  ?concept endp:P1 ?wd.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} 
order by lcase(?lemma)

Try it!

All concepts and English description

#title: "Training collection" concepts and English description

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>
PREFIX enp: <https://eneoli.wikibase.cloud/prop/>
PREFIX enps: <https://eneoli.wikibase.cloud/prop/statement/>
PREFIX enpq: <https://eneoli.wikibase.cloud/prop/qualifier/> 

select distinct ?concept ?conceptLabel ?termposLabel ?wikidata ?desc_en
       
where {   
  ?concept endp:P82 enwb:Q50. # Concepts in the "Training" collection
  ?concept schema:description ?desc_en. filter(lang(?desc_en)="en")
  optional {?concept endp:P1 ?wd. bind (iri(concat(str(wd:),?wd)) as ?wikidata)}
  optional {?concept endp:P92 ?termpos.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
} group by ?concept ?conceptLabel ?termposLabel ?wikidata ?desc_en 
order by lcase(?conceptLabel)

Try it!