Bibliographical Items

Source

Bibliographical items on this Wikibase stem from NeoCorpus Zotero group.

Database Queries

All bibliographical items

#title: All bibliographical items

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?item ?typeLabel ?date ?itemLabel 
       
where { 
  ?item endp:P5 enwb:Q2; endp:P6 ?type; endp:P30 ?date.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?date

Try it!

Publication years and number of articles

#title: Publication years and # of articles
#defaultView:BubbleChart
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?year (count(distinct ?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2; endp:P30 ?date.
  bind(str(YEAR(?date)) as ?year)
  # SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?year ?num_of_articles order by ?year

Try it!

Languages and number of articles

#title: Languages and # of articles
#defaultView:BarChart
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?languageLabel (count(distinct ?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2; endp:P7 ?language.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?languageLabel ?num_of_articles order by desc(?num_of_articles)

Try it!

Bibliographical item types and number of articles

#title: Bibliographical item types
#defaultView:BubbleChart

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?typeLabel (count(distinct ?item) as ?number_of_articles) 
       
where { 
  ?item endp:P5 enwb:Q2; endp:P6 ?type.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?typeLabel ?number_of_articles order by desc(?number_of_articles)

Try it!

Authors and number of articles

#title: Authors and number of articles

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?author ?authorLabel (count(?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2.
  ?item endp:P40 ?author.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?author ?authorLabel ?num_of_articles order by desc(?num_of_articles)

Try it!

Authors with Wikidata ID (federated query)

Zotero author name literals have been reconciled against Wikidata using OpenRefine.

#title: Authors with Wikidata ID (gets orcid, viaf, birthdate and description from Wikidata)
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX schema: <http://schema.org/>
PREFIX wdtn: <http://www.wikidata.org/prop/direct-normalized/>
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?author ?authorLabel ?wikidata ?orcid ?viaf ?birth ?desc
       
where { 
  ?author endp:P5 enwb:Q5; endp:P1 ?wd.
  bind (iri(concat("http://www.wikidata.org/entity/",?wd)) as ?wikidata)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  SERVICE <https://query.wikidata.org/sparql> {
           select ?wikidata ?orcid ?viaf ?birth ?desc
           where { ?wikidata schema:description ?desc. filter(lang(?desc)="en")
                  optional {?wikidata wdt:P569 ?birth.}
                  optional {?wikidata wdtn:P496 ?orcid.} optional {?wikidata wdtn:P214 ?viaf.}
           }
    }
}  order by lcase(?authorLabel)

Try it!