View source for Bibliographical Items

= Source =
Bibliographical items on this Wikibase stem from [https://www.zotero.org/groups/5449136/neocorpus/library NeoCorpus Zotero group].
= Database Queries =
== All bibliographical items ==
<sparql tryit="1">
#title: All bibliographical items

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?item ?typeLabel ?date ?itemLabel 
       
where { 
  ?item endp:P5 enwb:Q2; endp:P6 ?type; endp:P30 ?date.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?date
</sparql>
== All term-indexed bibliographical items ==
This query shows which NeoVoc terms are found in each article.
<sparql tryit="1">
#title: All term-indexed bibliographical items

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?item ?itemLabel ?langLabel (group_concat(str(?lemma)) as ?terms) 
       
where { 
  ?item endp:P5 enwb:Q2; endp:P7 ?lang; endp:P65 [wikibase:lemma ?lemma].
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?item ?itemLabel ?langLabel ?terms order by ?langLabel
</sparql>
== Lexemes found in article full texts, grouped to concepts ==
This query shows to which concepts the lexemes found in articles are linked.
<sparql tryit="1">
#title: Concepts linked to from (multilingual) lexeme senses found in articles.

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?concept ?conceptLabel (count(?item) as ?number_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2; endp:P7 ?lang; endp:P65 [ontolex:sense [endp:P12 ?concept]].
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?concept ?conceptLabel ?number_of_articles order by desc(?number_of_articles)
</sparql>

== Publication years and number of articles ==
<sparql tryit="1">
#title: Publication years and # of articles
#defaultView:BubbleChart
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?year (count(distinct ?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2; endp:P30 ?date.
  bind(str(YEAR(?date)) as ?year)
  # SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?year ?num_of_articles order by ?year
</sparql>

== Languages and number of articles ==
<sparql tryit="1">
#title: Languages and # of articles
#defaultView:BarChart
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?languageLabel (count(distinct ?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2; endp:P7 ?language.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?languageLabel ?num_of_articles order by desc(?num_of_articles)
</sparql>
== Bibliographical item types and number of articles ==
<sparql tryit="1">
#title: Bibliographical item types
#defaultView:BubbleChart

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?typeLabel (count(distinct ?item) as ?number_of_articles) 
       
where { 
  ?item endp:P5 enwb:Q2; endp:P6 ?type.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?typeLabel ?number_of_articles order by desc(?number_of_articles)
</sparql>
== Authors and number of articles ==
This query only considers authorships we have linked to Wikibase items describing persons ([[Item:Q624|example item]]). The linking process is ongoing.
<sparql tryit="1">
#title: Authors and number of articles

PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?author ?authorLabel (count(?item) as ?num_of_articles)
       
where { 
  ?item endp:P5 enwb:Q2.
  ?item endp:P40 ?author.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?author ?authorLabel ?num_of_articles order by desc(?num_of_articles)
</sparql>

== Authors with Wikidata ID (federated query) ==
Zotero author name literals have been reconciled against Wikidata using OpenRefine.
<sparql tryit="1">
#title: Authors with Wikidata ID (gets orcid, viaf, birthdate and description from Wikidata)
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX schema: <http://schema.org/>
PREFIX wdtn: <http://www.wikidata.org/prop/direct-normalized/>
PREFIX enwb: <https://eneoli.wikibase.cloud/entity/>
PREFIX endp: <https://eneoli.wikibase.cloud/prop/direct/>

select ?author ?authorLabel ?wikidata ?orcid ?viaf ?birth ?desc
       
where { 
  ?author endp:P5 enwb:Q5; endp:P1 ?wd.
  bind (iri(concat("http://www.wikidata.org/entity/",?wd)) as ?wikidata)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  SERVICE <https://query.wikidata.org/sparql> {
           select ?wikidata ?orcid ?viaf ?birth ?desc
           where { ?wikidata schema:description ?desc. filter(lang(?desc)="en")
                  optional {?wikidata wdt:P569 ?birth.}
                  optional {?wikidata wdtn:P496 ?orcid.} optional {?wikidata wdtn:P214 ?viaf.}
           }
    }
}  order by lcase(?authorLabel)
</sparql>